1 GOTO 3
2 SCRATCH R/1C,"REGION":SAVE DC R/1C,T("REGION")"REGION":LIST DC R/1C,"R":END 
3 PRINT HEX(03):PRINT TAB(30);"ПРОГРАММА":PRINT 
4 PRINT TAB(26);'"МОДЕЛЬ РЕГИОНА"'
5 N,Y7=0
10 P1=28:Z1=17:B1=13:H1=29:G1=20:K1=2:M,V,X,Y=0
15 Q4,Y4,Y5,Q,Q1,A1,A2,A3,A4,A5,A6,A7=0
20 A8=H1/14+G1^2*.002
22 M1=9:M2=4.123:M3=2.759:M4=-2.429:M5=13:M6=P1:M7=6.87:F1=H1
25 IF N<5THEN35
27 B1,M5=20:G1=16
28 M1=5:Z1=30:M4=-4.286
35 IF Y7=0THEN3150
110 IF G1<12THEN130
120 N=G1-11:GOTO 140
130 N=G1-12
140 F=0
150 PRINT HEX(03)
151 A9=A8:M8=V
160 PRINT "С О С Т О Я Н И Е   С И С Т Е М Ы-     ТЕКУЩ.ТУР     ПРЕДЫД.ТУР      ИСХ.ЗНАЧ."
170 PRINT "---------------------------------      ---------     ----------      ---------"
180 PRINTUSING "КАЧЕСТВО ЖИЗНИ В БАЛЛАХ               =###.###       ###.###         ###.###",N,A1,M1
190 L=-1-SQR(H1*H1*H1)/50
200 PRINTUSING "ПЛОТНОСТЬ НАСЕЛЕНИЯ (ЧЕЛ./КВ.КМ)      =###.###       ###.###         ###.###",-L,A2,M2
210 A8=100/F1*A8*(1-K1/8)
220 PRINTUSING "ИНТЕНСИВНОСТЬ РОСТА НАСЕЛЕНИЯ         =###.### %     ###.### %       ###.### %",A8,A3,M3
222 IF Z1>0THEN224
223 Z=-Z1/41:GOTO 240
224 IF Z1<37THEN230
225 Z=31-Z1:GOTO 240
230 Z=-Z1/7
240 PRINTUSING "КАЧЕСТВО ОКРУЖАЮЩЕЙ СРЕДЫ (В БАЛЛАХ)  =###.###       ###.###         ###.###",Z,A4,M4
260 PRINTUSING "СРЕДСТВА НА ПОДДЕРЖАНИЕ СРЕДЫ         =###.###       ###.###         ###.###",B1,A5,M5
270 PRINTUSING "В РАЗВИТИЕ Н/Х ВЛОЖЕНО СРЕДСТВ        =###.###       ###.###         ###.###",P1,A7,M6
280 R=(P1/5)*M2^(-1/3)*(-L)^(1/3)
290 H=SQR(H1*H1*H1)/123
300 V=V+R+H
310 PRINTUSING "ПРИБЫЛЬ (ДЕНЕЖНАЯ ЕДИНИЦА)            =###.###       ###.###         ###.###",V,A6,M7
315 IF M>25THEN940
320 A1=N:A2=-L:A3=A8:A4=Z:A5=B1:A6=V:A7=P1
325 X1=P1:X2=N:X3=H1
330 PRINT :PRINTUSING "                           ##  ГОД",M+1
331 IF F=1THEN340
332 IF Y7=0THEN334
333 IF M>=4THEN337
334 IF M>=12THEN337
335 PRINT :INPUT "ХОТИТЕ ЛИ ВЫ УЗНАТЬ О ВЗАИМОСВЯЗЯХ СИСТЕМЫ (ДА-1,НЕТ-0)",N
336 IF N=1THEN1400
337 IF M>=5THEN2900
340 PRINT :PRINT "НАЧНИТЕ РАСПРЕДЕЛЕНИЕ ПРИБЫЛИ"
341 PRINT "------- ------------- -------"
363 D4=V
365 S=V
366 D1=P1:D2=B1:D3=G1
400 PRINTUSING "ОСТАТОК ПРИБЫЛИ        =   ###.###",S;:INPUT "    СКОЛЬКО НА РАЗИТИЕ Н/Х",N1
410 IF N1>=0THEN440
413 PRINT "СОГЛАСИТЕСЬ,ЧТО СВЕРТЫВАТЬ РАЗВИТИЕ Н/Х НЕЦЕЛЕСООБРАЗНО.":GOTO 400
418 IF ABS(N1)<=P1THEN440
430 PRINT :PRINTUSING "ВЫ МОЖЕТЕ ОСВОБОДИТЬ НЕ БОЛЕЕ ###.### ЕДИНИЦ СРЕДСТВ",P1:GOTO 400
440 IF S-N1>=-.01THEN460
450 PRINT :PRINT "ВЫ РАСПРЕДЕЛИЛИ СРЕДСТВ БОЛЬШЕ,ЧЕМ У ВАС БЫЛО":PRINT :GOTO 400
460 S=S-N1:P1=P1+N1
465 IF S=0THEN702
490 PRINTUSING "ОСТАТОК ПРИБЫЛИ        =   ###.###",S;:INPUT "    СКОЛЬКО НА ПОДДЕРЖАНИЕ СРЕДЫ",N
500 IF N>0THEN530
510 PRINT "НА ПОДДЕРЖАНИЕ ОКРУЖАЮЩЕЙ СРЕДЫ СРЕДСТВА МОЖНО ТОЛЬКО ВКЛАДЫВАТЬ"
520 PRINT :GOTO 490
530 IF S-N>=-.01THEN550
540 PRINT :PRINT "ВЫ РАСПРЕДЕЛИЛИ СРЕДСТВ БОЛЬШЕ,ЧЕМ У ВАС БЫЛО":PRINT :GOTO 490
550 S=S-N:B1=B1+N
556 IF S=0THEN702
570 PRINTUSING "ОСТАТОК ПРИБЫЛИ        =   ###.###",S;:INPUT "    СКОЛЬКО В КАЧЕСТВО ЖИЗНИ    ",N1
580 IF N1>0THEN592
590 PRINT "В КАЧЕСТВО ЖИЗНИ СРЕДСТВА МОЖНО ТОЛЬКО ВКЛАДЫВАТЬ":PRINT :GOTO 570
592 IF M<21THEN603
593 IF Q4=2THEN603
594 IF N1<=V/2THEN603
595 Q4=Q4+1
596 PRINT HEX(12):PRINT :PRINT "БЛИЗОК КОНЕЦ ИГРЫ,А ВЫ ТАК НЕПРОПОРЦИОНАЛЬНО РАСПРЕДЕЛЯЕТЕ СРЕДСТВА."
597 PRINT "НЕ ЗАБЫВАЙТЕ О ТОМ,ЧТО ВАША ЦЕЛЬ-ВЫСОКОЕ КАЧЕСТВО ЖИЗНИ ПРИ  У М Е Л О М"
598 PRINT "УПРАВЛЕНИИ СИСТЕМОЙ В ЦЕЛОМ. ВАМ ПРИДЕТСЯ ПЕРЕРАСПРЕДЕЛИТЬ ПРИБЫЛЬ.";HEX(11)
599 INPUT "ДЛЯ ПРОДОЛЖЕНИЯ ДИАЛОГА НАЖАТЬ 'CR/LF'   ",N
600 GOTO 705
603 IF S-N1>=-.01THEN620
610 PRINT :PRINT "ВЫ РАСПРЕДЕЛИЛИ СРЕДСТВ БОЛЬШЕ,ЧЕМ У ВАС БЫЛО":PRINT :GOTO 570
620 S=S-N1:G1=G1+N1
630 IF S=0THEN702
640 PRINTUSING "ОСТАТОК ПРИБЫЛИ        =   ###.###",S;:INPUT "    СКОЛЬКО НА УПРАВЛ.РОЖД.     ",N2
650 IF ABS(N2)<=1THEN680
660 PRINT :PRINT "В БЛОКЕ УПРАВЛЕНИЯ РОЖДАЕМОСТЬЮ МОЖНО ОТВЕЧАТЬ ЧИСЛОМ (БЕЗ ЗНАКА ИЛИ СО ЗНАКОМ МИНУС) НЕ ПРЕВЫШАЮЩИМ 1":PRINT :GOTO 640
680 IF S-ABS(N2)>=-0.01THEN700
690 PRINT :PRINT "ВЫ РАСПРЕДЕЛИЛИ СРЕДСТВ БОЛЬШЕ,ЧЕМ У ВАС БЫЛО":PRINT :GOTO 640
700 S=S-ABS(N2)
702 PRINT :Q1=Q1+1:IF Q1>1THEN708
703 INPUT "ХОТИТЕ ЛИ ВЫ ПЕРЕРАСПРЕДЕЛИТЬ ПРИБЫЛЬ (ДА-1,НЕТ-0)",N
704 IF N=0THEN708
705 P1=D1:B1=D2:G1=D3:GOTO 365
708 K1=K1+N2:B=1-SQR(B1*B1*B1)/20:V=S
709 Q1=0
710 GOSUB 1290
720 Z1=Z1+B+P
730 GOSUB 1260
740 Z1=Z1+C
749 PRINT 
750 IF Z1<35THEN752
751 PRINT "НАСТУПИЛА ДЕГРАДАЦИЯ ОКРУЖАЮЩЕЙ СРЕДЫ"
752 IF Z1>0THEN754
753 Z=-Z1/41:GOTO 770
754 IF Z1<37THEN760
755 Z=31-Z1:GOTO 770
760 Z=-Z1/7
770 G1=G1+Z+L
780 GOSUB 1230
790 G1=G1+G
795 PRINT 
800 IF G1>=12THEN830
803 IF G1-12>A1THEN815
804 Q=Q+1:IF Q>4THEN1030
805 PRINT "БЛАГОСОСТОЯНИЕ НАРОДА УХУДШАЕТСЯ"
806 IF Q<3THEN810
807 PRINT "ПОДУМАЙТЕ, ГДЕ ВЫ ОШИБАЕТЕСЬ ?"
810 PRINT :INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
812 GOTO 820
815 Q=0
820 A8=-3^(-G1+1)*H1/20:F1=H1:H1=H1+A8:GOTO 845
830 A8=H1/14+G1*G1*.002
840 F1=H1
841 H1=H1+A8*(1-K1/8+1/(10*K1))
845 IF H1<=0THEN1030
850 IF G1>=12THEN870
860 Y1=G1-12:GOTO 880
870 Y1=G1-11
880 IF H1>=X3THEN885
882 Y1=Y1-3*(X3-H1)
885 IF M<>17THEN890
886 Y2=Y1
890 Y=Y+Y1
895 M=M+1
901 IF M=1THEN1770
902 IF M=2THEN1800
904 IF M=4THEN1900
906 IF M=8THEN2100
907 IF M=13THEN2200
908 IF M=20THEN2270
910 X=0:X1=P1:X2=Y1:X3=H1:GOTO 110
940 N=(Y+3*Y2)/M
950 PRINT :PRINT 
955 IF Q4<2THEN960
957 PRINT "ВАШИ НЕЛОГИЧНЫЕ ДЕЙСТВИЯ В КОНЦЕ ИГРЫ ПРИВЕЛИ К СНИЖЕНИЮ ОЦЕНКИ ДЕЯТЕЛЬНОСТИ"
958 N=N/1.2:PRINT 
960 PRINTUSING "         ОЦЕНКА ВАШЕЙ ДЕЯТЕЛЬНОСТИ     ###.###",N
970 PRINT "         ------ ----- ------------     -------"
980 IF N>=14THEN3000
990 IF N>9THEN1140
1000 IF N>5THEN1100
1010 IF N>0THEN1060
1020 GOTO 1060
1030 PRINT HEX(03):H1=0:PRINT HEX(12)
1055 PRINT "ВЫ ПОГУБИЛИ ВСЕ НАСЕЛЕНИЕ. ДАЛЬНЕЙШИЕ ВАШИ ДЕЙСТВИЯ БЕССМЫСЛЕННЫ.":PRINT HEX(11)
1056 PRINT "ПЕРЕД НАЧАЛОМ СЛЕДУЮЩЕЙ ИГРЫ ПРОЧТИТЕ ЕЩЕ РАЗ РУКОВОДСТВО К ИГРЕ":GOTO 1310
1060 PRINT "ВАМ НЕОБХОДИМО УЧИТЬСЯ ДУМАТЬ О БУДУЩЕМ И ПРИНИМАТЬ ВО ВНИМАНИЕ ВЗАИМОДЕЙСТВИЯ  МЕЖДУ ЭЛЕМЕНТАМИ СИСТЕМЫ, ТОГДА ВАШИ РЕШЕНИЯ БУДУТ БОЛЕЕ ОБДУМАННЫМИ И ВЫ       НАУЧИТЕСЬ ИЗБЕГАТЬ КРАЙНИХ РЕШЕНИЙ."
1090 GOTO 1310
1100 PRINT "НЕПЛОХО ДЛЯ НАЧАЛА, НО ВАШИ МЫСЛИ ОХВАТЫАЮТ ПОКА СЛИШКОМ КОРОТКИЙ ПРОМЕЖУТОК    ВРЕМЕНИ, НЕДОСТАТОЧНО ДАЛЕКО ЗАХОДЯЩИЙ В БУДУЩЕЕ. ПРИ БОЛЕЕ ПРЕДУСМОТРИТЕЛЬНЫХ  РЕШЕНИЯХ ВЫ СМОЖЕТЕ УЛУЧШИТЬ РЕЗУЛЬТАТ В СЛЕДУЩЕЙ ИГРЕ.":GOTO 1310
1140 PRINT "ВЫ СМОГЛИ ДОСТАТОЧНО ХОРОШО ПОДЧИНИТЬ СЕБЕ ФУНКЦИОНИРОВАНИЕ ИМИТАЦИОННОЙ СИСТЕМЫХОТЯ СОСТОЯНИЕ, КОТОРОГО ВЫ ДОСТИГЛИ, НЕ САМОЕ ЛУЧШЕЕ. В КОНЦЕ КОНЦОВ ВЫ ДОСТИГ-ЛИ СОСТОЯНИЯ УСТОЙЧИВОГО РАВНОВЕСИЯ, ГАРАНТИРУЮЩЕГО ОПРЕДЕЛЕННЫЙ УДОВЛЕТВОРИ-"
1150 PRINT "ТЕЛЬНЫЙ УРОВЕНЬ БЛАГОСОСТОЯНИЯ НАРОДА В БУДУЩЕМ":GOTO 1310
1190 PRINT "ВЫ ИМЕЛИ БОЛЬШОЙ УСПЕХ, БЛАГОДАРЯ РАЗУМНЫМ И ПРЕДУСМОТРИТЕЛЬНЫМ РЕШЕНИЯМ.       ВЫ ЗНАЧИТЕЛЬНО УЛУЧШИЛИ СОСТОЯНИЕ СИСТЕМЫ.":GOTO 1310
1220 G=4-G1/4:RETURN 
1230 IF G1>=20THEN1220
1240 G=3-G1/4:RETURN 
1250 C=-(50-Z1)/5:RETURN 
1260 IF Z1>=30THEN1250
1265 IF Z1>=0THEN1270
1267 C=2^Z1:RETURN 
1270 C=-(Z1*Z1+45*Z1+250)/(10*Z1+250):RETURN 
1280 P=(2*P1-45)/5:RETURN 
1290 IF P1>=45THEN1280
1300 P=P1/5:RETURN 
1310 PRINT :PRINT 
1311 PRINT HEX(12):PRINT "ИЗМЕНЕНИЯ В СОСТОЯНИИ МОДЕЛИ В РЕЗУЛЬТАТЕ ВАШИХ ДЕЙСТВИЙ":PRINT HEX(11)
1312 PRINT "--------- - --------- ------ - ---------- ----- --------"
1313 N=Y1-M1
1320 IF N>=0THEN1325
1321 PRINTUSING "КАЧЕСТВО ЖИЗНИ ПО СРАВНЕНИЮ С ИСХОДНЫМ ЗНАЧЕНИЕМ УХУДШИЛОСЬ НА ###.###",N:GOTO 1330
1325 PRINTUSING "КАЧЕСТВО ЖИЗНИ ПО СРАВНЕНИЮ С ИСХОДНЫМ ЗНАЧЕНИЕМ ВЫРОСЛО НА ###.###",N
1330 N=1+SQR(H1*H1*H1)/50-M2
1334 IF N>=0THEN1337
1335 PRINTUSING "ПЛОТНОСТЬ НАСЕЛЕНИЯ ПО СРАВНЕНИЮ С ИСХОДНЫМ ЗНАЧЕНИЕМ УМЕНЬШИЛАСЬ НА ###.###",N
1336 GOTO 1340
1337 PRINTUSING "ПЛОТНОСТЬ НАСЕЛЕНИЯ ПО СРАВНЕНИЮ С ИСХОДНЫМ ЗНАЧЕНИЕМ ВЫРОСЛА НА ###.###",N
1338 IF Z1>0THEN1340
1339 N=-Z1/41-M4:GOTO 1344
1340 IF Z1<37THEN1342
1341 N=31-Z1-M4:GOTO 1344
1342 N=-Z1/7-M4
1344 IF N>=0THEN1347
1345 PRINTUSING "КАЧЕСТВО ОКРУЖАЮЩЕЙ СРЕДЫ ПО СРАВНЕНИЮ С ИСХОДНЫМ ЗНАЧЕНИЕМ УХУДШИЛАСЬ НА ###.###",N
1346 GOTO 1350
1347 PRINTUSING "КАЧЕСТВО ОКРУЖАЮЩЕЙ СРЕДЫ ПО СРАВНЕНИЮ С ИСХОДНЫМ ЗНАЧЕНИЕМ УЛУЧШИЛОСЬ НА ###.###",N
1350 N=D4-M7
1354 IF N>=0THEN1357
1355 PRINTUSING "ПРИБЫЛЬ УМЕНЬШИЛАСЬ НА ###.###",N:GOTO 1360
1357 PRINTUSING "ПРИБЫЛЬ ВЫРОСЛА НА ###.###",N
1360 Y7=1
1362 PRINT :PRINT 
1363 PRINT "ПРОАНАЛИЗИРУЙТЕ ПОЛУЧЕННЫЙ РЕЗУЛЬТАТ."
1364 INPUT "ЕСЛИ ВЫ ЖЕЛАЕТЕ СЫГРАТЬ ЕЩЕ РАЗ, НАБЕРИТЕ 1 И НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
1365 IF N=1THEN10
1366 PRINT HEX(03):PRINT "   РАЗРАБОТЧИКАМИ МАШИННОЙ РЕАЛИЗАЦИИ ОБУЧАЮЩЕЙ ИМИТАЦИОННОЙ ИГРЫ"
1367 PRINT HEX(12):PRINT "                      М О Д Е Л Ь  Р Е Г И О Н А ":PRINT HEX(11)
1368 PRINT :PRINT :PRINT :GOTO 3070
1400 PRINT HEX(03)
1401 PRINT "КАКУЮ ИЗ ПЕРЕЧИСЛЕННЫХ ЗАВИСИМОСТЕЙ ВАМ ПРОИЛЛЮСТРИРОВАТЬ:"
1402 PRINT "----- -- ------------- ------------ --- -----------------"
1403 PRINT "1.ОТ ЧЕГО ЗАВИСИТ ПРИБЫЛЬ?":PRINT 
1405 PRINT "2.ОТ ЧЕГО ЗАВИСИТ УРОВЕНЬ ЗАГРЯЗНЕНИЯ ОКРУЖАЮЩЕЙ СРЕДЫ?":PRINT 
1407 PRINT "3.ОТ ЧЕГО ЗАВИСИТ ИНТЕНСИВНОСТЬ РОСТА НАСЕЛЕНИЯ?":PRINT 
1409 PRINT "4.ОТ ЧЕГО ЗАВИСИТ БЛАГОСОСТОЯНИЕ НАРОДА (КАЧЕСТВО ЖИЗНИ)?":FOR I=1TO5:PRINT :NEXT I
1414 F=1
1415 PRINT "ЕСЛИ ЗАВИСИМОСТИ ВАС БОЛЬШЕ НЕ ИНТЕРЕСУЮТ, ВВЕДИТЕ 0; ЕСЛИ ХОТИТЕ ПОЛУЧИТЬ ОТВЕТ НА КАКОЙ-НИБУДЬ ИЗ ПЕРЕЧИСЛЕННЫХ ВОПРОСОВ, ВВЕДИТЕ НОМЕР ВОПРОСА":INPUT N
1417 PRINT HEX(03)
1420 IF N=1THEN1510
1430 IF N=2THEN1570
1440 IF N=3THEN1610
1450 IF N=4THEN1650
1500 N=A1:A8=A9:V=M8:GOTO 150
1510 PRINT "ПРИБЫЛЬ РАСТЕТ ЗА СЧЕТ:":PRINT "------- ------ -- ----"
1511 PRINT "                             1.РАЗВИТИЯ Н/Х,"
1512 PRINT "                             2.РОСТА НАСЕЛЕНИЯ."
1515 PRINT :PRINT "                             Y-ПРИБЫЛЬ"
1520 FOR I=1TO6STEP.5
1525 PRINT TAB(30);"I";TAB(78-I*I);"$";TAB(79-6*I);"*"
1530 NEXT I
1540 PRINT "                              -------------------------------------------------"
1541 PRINT "                                                                             X"
1542 PRINT :PRINT "            ГДЕ $ - ЗАВИСИМОСТЬ ИЗМЕНЕНИЯ ВЕЛИЧИНЫ ПРИБЫЛИ ОТ ЧИСЛ. НАСЕЛЕНИЯ."
1543 PRINT "                * - ЗАВИСИМОСТЬ ИЗМЕНЕНИЯ ВЕЛИЧИНЫ ПРИБЫЛИ ОТ РАЗВИТИЯ Н/Х.":PRINT 
1550 INPUT "ЕСЛИ ХОТИТЕ ПРОДОЛЖИТЬ ДИАЛОГ, НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
1560 GOTO 1400
1570 PRINT "УРОВЕНЬ ЗАГРЯЗНЕНИЯ ПОВЫШАЕТСЯ ЗА СЧЕТ РАЗВИТИЯ Н/Х,"
1572 PRINT "УРОВЕНЬ ЗАГРЯЗНЕНИЯ ПОНИЖАЕТСЯ ЗА СЧЕТ СРЕДСТВ, ВЛОЖЕННЫХ В ПОДДЕРЖАНИЕ СРЕДЫ.":PRINT :PRINT 
1575 PRINT " Y-УРОВЕНЬ ЗАГРЯЗНЕНИЯ                  Y-УРОВЕНЬ ЗАГРЯЗНЕНИЯ"
1576 FOR I=1TO3.5STEP.3
1580 PRINT TAB(1);"I";TAB(32-2*I*I);"$";TAB(40);"I";TAB(40+I*I*I);"*"
1590 NEXT I
1600 PRINT " ----------------------------------     --------------------------------------"
1601 PRINT "      РАЗВИТИЕ Н/Х                            КОЛИЧЕСТВО ВЛОЖЕННЫХ СРЕДСТВ"
1603 PRINT :PRINT :GOTO 1550
1610 PRINT "ИНТЕНСИВНОСТЬ РОСТА НАСЕЛЕНИЯ ЗАВИСИТ ОТ:"
1614 PRINT "                            1.КАЧЕСТВА ЖИЗНИ (ГРАФИК *),"
1615 PRINT "                            2.УПРАВЛЕНИЕ РОЖД.(ЧЕМ БОЛЬШЕ ВЛОЖЕННЫХ СРЕДСТВ, ТЕM                              НИЖЕ ИНТЕНСИВНОСТЬ РОСТА НАСЕЛЕНИЯ (ГРАФИК .)."
1617 PRINT "                            3.ЧИСЛЕННОСТЬ НАСЕЛЕНИЯ (С РОСТОМ НАСЕЛЕНИЯ ИНТЕН-                                СИВНОСТЬ РОСТА СНИЖАЕТСЯ)."
1618 PRINT "                              Y-ИНТЕНС.РОСТА НАСЕЛЕНИЯ"
1620 FOR I=1TO4STEP.5
1630 PRINT TAB(7*I);".";TAB(30);"I";TAB(51-I*I);"*";TAB(50+I*I);"."
1635 NEXT I
1636 PRINT "-------------------------------------------------------------------------------X"
1637 FOR I=2TO5STEP.5
1638 PRINT TAB(100/I/I);"*";TAB(30);"I";TAB(20+7*I);"."
1640 NEXT I
1644 PRINT :GOTO 1550
1650 PRINT "КАЧЕСТВО ЖИЗНИ ЗАВИСИТ ОТ:                                                                   1. ОКРУЖАЮЩЕЙ СРЕДЫ (ЧЕМ ЛУЧШЕ СРЕДА, ТЕМ ВЫШЕ КАЧЕСТВО ЖИЗНИ,                  2. ПЛОТНОСТИ НАСЕЛЕНИЯ (ЧЕМ ВЫШЕ ПЛОТНОСТЬ, ТЕМ ХУЖЕ КАЧ. ЖИЗНИ),"
1656 PRINT "             3. ЕСТЕСТВЕННОЙ САМОРЕГУЛИРУЕМОСТИ, КОТОРАЯ ЗАСТАВЛЯЕТ УОВЕНЬ КА-                  ЧЕСТВА ЖИЗНИ СРЕМИТЬСЯ ОТ КРАЙНИХ ХОРОШИХ И КРАЙНИХ ПЛОХИХ                      ЗНАЧЕНИЙ К СРЕДНИМ"
1670 PRINT "             4. ВОЖЕННЫХ СРЕДСТВ (ЧЕМ БОЛЬШЕ ВКЛАДЫВАЕТЕ, ТЕМ ВЫШЕ КАЧЕСТВО                     ЖИЗНИ"
1680 PRINT "                                   Y-КАЧЕСВО ЖИЗНИ"
1681 FOR I=1TO3STEP.5
1682 PRINT TAB(39);"I";TAB(40+I^(3/2));"$";TAB(67-I*I*I);"*"
1683 NEXT I
1685 PRINT "     ---------------------------------------------------------------------X"
1687 FOR I=2TO3STEP.2
1688 PRINT TAB(17+150/I/I/I);"*";TAB(39);"I";TAB(39+I^3.2);"$"
1690 NEXT I
1694 PRINT "     ГДЕ $-ЗАВИСИМОСЬ ИЗМЕНЕНИЯ КАЧЕСТВА ЖИЗНИ ОТ ПЛОТНОСТИ НАСЕЛЕНИЯ,"
1695 PRINT "         *-ЗАВИСИМОСЬ ИЗМЕНЕНИЯ КАЧЕСТВА ЖИЗНИ ОТ СОСОЯНИЯ ОКРУЖАЮЩЕЙ СРЕДЫ."
1700 GOTO 1550
1770 PRINT HEX(03)
1775 IF Y7=1THEN910
1780 PRINT "ОЧЕВИДНО ВЫ УЖЕ ДОГАДАЛИСЬ, ЧТО ОТРИЦАТЕЛЬНЫЕ ЧИСЛА ХАРАКТЕРИЗУЮТ ПЛОХОЕ        СОСТОЯНИЕ ТОГО ИЛИ ИНОГО ПАРАМЕТРА МОДЕЛИ, А ПОЛОЖАТЕЛЬНЫЕ - ХОРОШЕЕ"
1786 FOR I=1TO8:PRINT :NEXT I
1787 INPUT "ЕСЛИ ХОТИТЕ ПРОДОЛЖИТЬ ДИАЛОГ, НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
1795 GOTO 910
1800 PRINT HEX(03)
1810 IF B1-A5<6THEN1835
1815 IF K1>2THEN1825
1820 GOTO 910
1825 PRINT "ХОТЕЛОСЬ БЫ ВАМ НАПОМНИТЬ, ЧТО УВЕЛИЧЕНИЕ ВЛОЖЕННЫХ СРЕДСТВ В УПРАВЛЕНИЕ        РОЖДАЕМОСТЬЮ ВЕДЕТ К ПОНИЖЕНИЮ ИНТЕНСИВНОСТИ РОСТА НАСЕЛЕНИЯ"
1830 GOTO 1870
1835 PRINT "ВЫ НЕДООЦЕНИВАЕТЕ ПАГУБНОЕ ВЛИЯНИЕ ЗАГРЯЗНЕНИЯ ОКРУЖАЮЩЕЙ СРЕДЫ НА КАЧЕСТВО"
1840 INPUT "ЖИЗНИ;   НАЖМИТЕ 'CR/LF'",N
1841 IF B1<=M5THEN1815
1842 FOR I%=1TO9:PRINT :NEXT I%
1843 IF B1-M5<=P1-M6THEN1860
1850 GOTO 1815
1860 PRINT "ОЧЕВИДНО ВАМ ПРИДЕТСЯ ПОДСКАЗАТЬ, ЧТО ПРИ ДАННОМ СОСТОЯНИИ МОДЕЛИ НЕ ВЫГОДНО    ВКЛАДЫВАТЬ В Н/Х СРЕДСТВ БОЛЬШЕ, ЧЕМ В ПОДДЕРЖАНИЕ ОКРУЖАЮЩЕЙ СРЕДЫ."
1870 FOR I%=1TO5:PRINT :NEXT I%
1871 INPUT "ЕСЛИ ХОТИТЕ ПРОДОЛЖИТЬ ДИАЛОГ, НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
1900 IF G1>1THEN910
1910 PRINT HEX(03)
1920 PRINT "ОСОБОЕ ВНИМАНИЕ ОБРАТИТЕ НА ТО, ОТ ЧЕГО ЗАВИСИТ КАЧЕСТВО ЖИЗНИ."
1921 PRINT :INPUT "ДЛЯ ПРОДОЛЖЕНИЯ ДИАЛОГА НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
2100 IF Z<-1.5THEN2150
2120 GOTO 910
2150 PRINT HEX(03)
2155 PRINT "НЕ ЗАБЫВАЙТЕ О ТОМ, ЧТО ЗАГРЯЗНЕНИЕ ОКРУЖАЮЩЕЙ СРЕДЫ ОТРИЦАТЕЛЬНО СКАЗЫВАЕТСЯ   НА КАЧЕСТВЕ ЖИЗНИ. ЛУЧШЕ ВСЕГО ПАРАМЕТР, ХАРАКТЕРИЗУЮЩИЙ УРОВНЬ ЗАГРЯЗНЕНИЯ     ДЕРЖАТЬ ПОЛОЖИТЕЛЬНЫМ"
2160 FOR I%=1TO9:PRINT :NEXT I%
2165 INPUT "ДЛЯ ПРОДОЛЖЕНИЯ ДИАЛОГА НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
2170 GOTO 2120
2200 PRINT HEX(03)
2215 PRINT "ВЫ СЫГРАИ 13 ТУРОВ (ПОЛОВИНУ ИГРЫ). ПОМНИТЕ, ЧТО ВЫ ДОЛЖНЫ СОЗДАТЬ ВСЕ УСЛОВИЯ, ЧТОБЫ ДОБИТЬСЯ НАИБОЛЕЕ ИНТЕНСИВНОГО РОСТА БЛАГОСОСТОЯНИЯ НАРОДА С УЧЕТОМ       НЕПРЕРЫВНОГО УЛУЧШЕНИЯ СОСТОЯНИЯ СИСТЕМЫ."
2221 FOR I%=1TO6:PRINT :NEXT I%
2222 INPUT "ДЛЯ ПРОДОЛЖЕНИЯ ДИАЛОГА НАЖМИТЕ КЛАВИШУ 'CR/LF'",N
2227 GOTO 910
2270 PRINT HEX(03)
2275 PRINT "ВАМ ОСТАЛОСЬ СЫГРАТЬ 5 ТУРОВ. ПОМНИТЕ, ЧТО ГЛАВНАЯ ВАША ЦЕЛЬ - ДОСТИЧЬ НАИВЫС-  ШЕГО КАЧЕСТВА ЖИЗНИ. ДОКАЖИТЕ, ЧТО СОЗДАННОЕ ВАМИ СОСТОЯНИЕ СИСТЕМЫ СПОСОБСТВУ- ЕТ ПОВЫШЕНИЮ КАЧЕСТВА ЖИЗНИ. СТАРАЙТЕСЬ СТАБИЛЬНО УВЕЛИЧИВАТЬ КАЧЕСТВО ЖИЗНИ."
2280 PRINT "ОТ ЭТОГО ЗАВИСИТ ОЦЕНКА ВАШЕЙ ДЕЯТЕЛЬНОСТИ."
2285 GOTO 1870
2500 Y3=A1-INT(A1)
2510 IF Y3<12/13THEN2540
2520 PRINT "НАГНЕТАНИЕ МЕЖДУНАРОДНОЙ НАПРЯЖЕННОСТИ ИМПЕРИАЛИСТИЧЕСКИМИ ГОСУДАРСТВАМИ И НЕ-  ОБХОДИМОСТЬ ОТВЕТНЫХ МЕР ПРИВЕЛО К ТОМУ, ЧТО ЧАСТЬ БЮДЖЕТА ПЕРЕДАНА ВОЕННЫМ ВЕ- ДОМСТВАМ. В ДВУХ ПОСЛЕДНИХ ТУРАХ ВЫ ЛИШАЕТЕСЬ КАЖДЫЙ РАЗ ДВУХ ЕДИНИЦ ПРИБЫЛИ."
2530 V=V-2:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2540 IF Y3<11/13THEN2570
2550 PRINT "ВВЕДЕНИЕ ВСЕОБЩЕГО ЭКОЛОГИЧЕСКОГО ОБРАЗОВАНИЯ И ЭФФЕКТИВНАЯ ПРОПАГАНДА В ОБЛАСТИОХРАНЫ ОКРУЖАЮЩЕЙ СРЕДЫ ПРИВЕЛО К ПОВЫШЕНИЮ УРОВНЯ ЭКОЛОГИЧЕСКОГО СОЗНАНИЯ, ЧТО БЛАГОПРИЯТНО СКАЗАЛОСЬ НА ПОВЫШЕНИИ БЛАГОСОСТОЯНИЯ НАСЕЛЕНИЯ. УРОВЕНЬ БЛАГОСОС-"
2556 PRINT "TOЯНИЯ НАСЕЛЕНИЯ ПОВЫСИЛСЯ НА 2 ЕДИНИЦЫ. КРОМЕ ТОГО, ВЫ ИМЕЕТЕ 1 ДОПОЛНИТЕЛЬНУЮ ЕДИНИЦУ ПРИБЫЛИ ДЛЯ СЛЕДУЩЕГО ТУРА."
2560 G1=G1+2:V=V+1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2570 IF Y3<10/13THEN2600
2580 PRINT "ОБРУШИВШИЙСЯ НА РЕГИОН УРАГАН НАНЕС БОЛЬШОЙ МАТЕРИАЛЬНЫЙ УЩЕРБ СЕЛЬСКОМУ ХО-    ЗЯЙСТВУ И ПРОМЫШЛЕННОСТИ. Н/Х ЛИШАЕТСЯ 5 ЕДИНИЦ СРЕДСТВ, ИСТРАЧЕННЫХ НА УСТРА-  НЕНИЕ ПОСЛЕДСТВИЙ СТИХИЙНОГО БЕДСТВИЯ."
2590 P1=P1-5:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2600 IF Y3<9/13THEN2630
2610 PRINT "ЭФФЕКТИВНОЕ ДЕЙСТВИЕ ЗАКОНОДАТЕЛЬСТВА, КОНТРОЛИРУЮЩЕГО ЗАГРЯЗНЕНИЕ ОКРУЖАЮЩЕЙ   СРЕДЫ, ПРИВЕЛО К ШИРОКОМУ ВНЕДРЕНИЮ ЗАМКНУТЫХ ЦИКЛОВ В ТЕХНОЛОГИИ ПРОИЗВОДСТВ.  ЭТО ЗНАЧИТЕЛЬНО СНИЗИЛО КОЛИЧЕСТВО СТОЧНЫХ ВОД И ОТХОДОВ. СРЕДА УЛУЧШАЕТСЯ";
2617 N=-2:GOSUB 2940
2618 PRINTUSING "       НА ##.## , КРОМЕ ТОГО, ВЫ ИМЕЕТЕ ОДНУ ДОПОЛНИТЕЛЬНУЮ ЕДИНИЦУ ПРИБЫЛИ.",Y9
2620 Z1=Z1-2:V=V+1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2630 IF Y3<8/13THEN2660
2640 PRINT "ПЕРЕНОС НА РЕГИОН ИЗ СОСЕДНИХ СТРАН ВОЗДУШНЫХ МАСС, ЗАГРЯЗНЕННЫХ ВРЕДНЫМИ ДЛЯ   ПРИРОДЫ ИНГРАДИЕНТАМИ, УХУДШИЛО КАЧЕСТВО ОКРУЖАЮЩЕЙ СРЕДЫ НА 0.29, 2 ЕДИНИЦЫ    ПРИБЫЛИ ПЕРЕДАНЫ НА КОМПЕНСАЦИОННЫЕ МЕРОПРИЯТИЯ."
2650 Z1=Z1+.29:V=V-2:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2660 IF Y3<7/13THEN2690
2670 PRINT "РОСТ ПРОИЗВОДСТВА ЗА СЧЕТ ВОЗОБНОВИМЫХ ИСТОЧНИКОВ СДЕЛАЛИ БЕЗОТХОДНЫЕ ЭНЕРГОЕМ- КИЕ ТЕХНОЛОГИИ ВЫГОДНЫМИ ДЛЯ ПРОМЫШЛЕННЫХ ПРЕДПРИЯТИЙ. КОЛИЧЕСТВО СРЕДСТВ, ВЛО- ЖЕННЫХ НА ПОДДЕРЖАНИЕ СРЕДЫ, УВЕЛИЧИВАЕТСЯ НА 3 ЕДИНИЦЫ, ОДНОВРЕМЕННО ВЫ ЛИША-"
2680 PRINT "ЕТЕСЬ 1 ЕДИНИЦЫ ПРИБЫЛИ, ЗАТРАЧЕННОЙ НА НАУЧНЫЕ ИССЛЕДОВАНИЯ В ОБЛАСТИ ЭНЕРГЕ-  ТИКИ."
2681 B1=B1+3:V=V-1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2690 IF Y3<7/13THEN2720
2700 PRINT "НЕОБХОДИМОСТЬ РАСШИРЕНИЯ НАУЧНЫХ ИССЛЕДОВАНИЙ И ЭКСПЕРИМЕНТАЛЬНЫХ РАБОТ ДЛЯ     ИЗУЧЕНИЯ МУТАГЕННЫХ И ЭКОЛОГО-ТОКСИКОЛОГИЧЕСКИХ СВОЙСТВ ВНОВЬ СИНТЕЗИРОВАННЫХ   ХИМИЧЕСКИХ ВЕЩЕСТВ ПОТРЕБОВАЛО ДОПОЛНИТЕЛЬНЫХ НЕЗАПЛАНИРОВАННЫХ СРЕДСТВ."
2705 PRINT "ВЫ ЛИШАЕТЕСЬ 2 ЕДИНИЦ ПРИБЫЛИ."
2710 V=V-2:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2720 IF Y3<6/13THEN2750
2730 PRINT "ВОЗРОСШИЕ УСИЛИЯ В ОБЛАСТИ ПРОСВЕЩЕНИЯ ПРИВЕЛИ К УСОВЕРШЕНСТВОВАНИЮСИСТЕМЫ УП-  РАВЛЕНИЯ ДЕМОГРАФИЧЕСКИМИ ПРОЦЕССАМИ В РЕГИОНЕ. КОЛИЧЕСТВО СРЕДСТВ В УПРАВЛЕНИЕ РОЖДАЕМОСТЬЮ УВЕЛИЧИЛОСЬ НА 1 ЕДИНИЦУ."
2740 K1=K1+1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2750 IF Y3<5/13THEN2780
2760 PRINT "РАЗРАБОТКА И ВНДРЕНИЕ В С/Х БИОЛОГИЧЕСКИХ СПОСОБОВ ЗАЩИТЫ РАСТЕНИЙ И ИНТЕНСИФИ- КАЦИЯ ЕГО НА ОСНОВЕ ОРГАНИЧЕСКИХ УДОБРЕНИЙ И ПРИНЦИПИАЛЬНО НОВЫХ ПРИЕМОВ ОБРА-  БОТКИ ЗАМЛИ ПОЗВОЛИЛО УЛУЧШИТЬ КАЧЕСТВО СРЕДЫ. КОЛИЧЕСТВО ВЛОЖЕННЫХ ВАМИ "
2765 PRINT "СРЕДСТВ НА ПОДДЕРЖАНИЕ СРЕДЫ В СЛЕДУЮЩЕМ ТУРЕ УДВАИВАЕТСЯ."
2770 Y4=1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2780 IF Y3<4/13THEN2810
2790 PRINT "РАЗВИТИЕ ЭЛЕКТРОТРАНСПОРТА СДЕЛАЛО ВОЗМОЖНЫМ ЗНАЧИТЕЛЬНО УВЕЛИЧИТЬ ОБ'ЕМ И СКО- РОСТЬ ПВССВЖИРСКИХ ПЕРЕВОЗОК В ГОРОДАХ РЕГИОНА И УМЕНЬШИТЬ ВЫБРОС ЗАГРЯЗНЕНИЙ."
2793 N=-2:GOSUB 2940
2794 PRINTUSING "ОКРУЖАЮЩАЯ СРЕДА УЛУЧШАЕТСЯ НА ##.## , УРОВЕНЬ БЛАГОСОСТОЯНИЯ НАРОДА ПОВЫСИЛСЯ  НА 1 ЕДИНИЦУ. КРОМЕ ТОГО, ВЫ ИМЕЕТЕ 1 ДОПОЛНИТЕЛЬНУЮ ЕДИНИЦУ ПРИБЫЛИ.",Y9
2800 Z1=Z1-2:G1=G1+1:V=V+1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2810 IF Y3<3/13THEN2840
2820 PRINT "МНОГОЛЕТНЯЯ ЗАСУХА, А ТАК ЖЕ ИНТЕНСИВНОЕ ИСПОЛЬЗОВАНИЕ ВОДОЕМОВ И РЕКРЕЦИОННЫХ  ТЕРРИТОРИЙ РЕГИОНА УХУДШИЛИ ЕГО СОСТОЯНИЕ И ПОТРЕБОВАЛИ ЗНАЧИТЕЛЬНЫХ КАПИТАЛО-  ВЛОЖЕНИЙ НА ВОСТАНОВЛЕНИЕ И БЛАГОУСТРОЙСТВО. УРОВЕНЬ КАЧЕСТВА ЖИЗНИ СНИЗИЛСЯ"
2824 PRINT " НА 3 ЕДИНИЦЫ, ВЫ ПОТЕРЯЛИ 1 ЕДИНИЦУ ПРИБЫЛИ."
2830 G1=G1-3:V=V-1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2840 IF Y3<2/13THEN2870
2850 PRINT "РАЗРАБОТКА И ВНЕДРЕНИЕ АВТОМАТИЗИРОВАННОЙ СИСТЕМЫ МНОГОУРОВНЕВОГО УПРАВЛЕНИЯ,   ВКЛЮЧАЮЩЕГО ВСЕ ИСТОЧНИКИ ЗАГРЯЗНЕНИЯ ОКРУЖАЮЩЕЙ СРЕДЫ, ПРИВЕЛИ К УЛУЧШЕНИЮ ЕЕ  КАЧЕСТВА НА 2 ЕДИНИЦЫ. КРОМЕ ТОГО, ВЫ ПОЛУЧИЛИ 1 ЕДИНИЦУ ПРИБЫЛЫ."
2860 Z1=Z1-2:V=V+1:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2870 PRINT "ВНЕДРЕНА НОВАЯ ТЕХНОЛОГИЯ ПОЛУЧЕНИЯ АЛЮМИНИЯ С ЭКОНОМИЧНЫМ ИСПОЛЬЗОВАНИЕМ ЭНЕР- ГИИ. КОЛИЧЕСТВО СРЕДСТВ НА ПОДДЕРЖАНИЕ ОКРУЖАЮЩЕЙ СРЕДЫ УВЕЛИЧИЛОСЬ НА 2 ЕДИНИ- ЦЫ."
2880 B1=B1+2:INPUT "НАЖМИТЕ КЛАВИШУ 'CR/LF'",N:GOTO 340
2900 IF M>5THEN2920
2907 IF Y7=1THEN2925
2910 PRINT :PRINT "ЕСЛИ ВАМ КАЖЕТСЯ, ЧТО ВЫ МОГЛИ БЫ СПРАВИТЬСЯ С БОЛЕЕ СЛОЖНОЙ СИСТЕМОЙ,          ВВЕДИТЕ 1.";
2915 INPUT " В ПРОТИВНОМ СЛУЧАЕ НАЖМИТЕ 'CR/LF'  ",Y6
2920 IF Y7=1THEN2925
2923 IF Y6=0THEN340
2925 Y5=Y5+1:IF Y5=1THEN2500
2930 IF Y5<=5THEN340
2935 Y5=1:GOTO 2500
2940 IF Z1+N>0THEN2950
2945 Y9=-A4-(Z1+N)/41:RETURN 
2950 IF Z1+N<37THEN2960
2955 Y9=31-(Z1+N)-A4:RETURN 
2960 Y9=-A4-(Z1+N)/7:RETURN 
3000 IF N>=16THEN3030
3010 PRINT HEX(12):PRINT "ВАШИ ДЕЙСТВИЯ МОЖНО ОЦЕНИТЬ НА ОТЛИЧНО, ВЫ Н А У Ч И Л И С Ь УПРАВЛЯТЬ СИСТЕМОЙ, НО ВСЕ ЕЩЕ НЕ ЧУВСТВУЕТЕ УВЕРЕННОСТИ В СВОИХ СИЛАХ. ПОВЕРЬТЕ В НИХ И ВЫ МОЖЕТЕ"
3015 PRINT "ДОСТИГНУТЬ И ЛУЧШИХ РЕЗУЛЬТАТОВ, ЕСЛИ БУДЕТЕ РЕШИТЕЛЬНЕЙ И ЦЕЛЕНАПРАВЛЕННЕЙ.":PRINT HEX(11)
3016 PRINT "ПОПРОБУЙТЕ СЫГРАТЬ ЕЩЕ ЛУЧШЕ.":GOTO 1310
3030 IF N>=18THEN3060
3040 PRINT HEX(12):PRINT "О Т Л И Ч Н О ! ВЫ ДОБИЛИСЬ БОЛЬШИХ УСПЕХОВ. ПОЗДРАВЛЯЕМ ВАС!":PRINT HEX(11):GOTO 1310
3060 PRINT HEX(12):PRINT TAB(25);"П Р Е К Р А С Н О !":PRINT HEX(11):GOTO 1310
3070 PRINT :PRINT "ЯВЛЯЮТСЯ СЛЕДУЮЩИЕ СОТРУДНИКИ О Т С О  И  Б И О -ФАКА К Г У:"
3075 PRINT :PRINT TAB(30);"МАМАЕВА Л.А."
3080 PRINT TAB(30);"КОТОВ Ю.С."
3085 PRINT TAB(30);"ТАРКАЕВ А.Н."
3100 PRINT HEX(12):PRINT TAB(30);"Д О  С В И Д А Н И Я !":PRINT HEX(11)
3150 PRINT HEX(03)
3160 PRINT TAB(12);"МАШИННАЯ РЕАЛИЗАЦИЯ ОБУЧАЮЩЕЙ ИМИТАЦИОННОЙ ИГРЫ"
3170 PRINT HEX(12):PRINT TAB(22);"М О Д Е Л Ь  Р Е Г И О Н А":PRINT HEX(11)
3190 INPUT "ВАС ОЗНАКОМИТЬ С ПРАВИЛАМИ ИГРЫ? (ДА-1,НЕТ-0)    ",N
3200 IF N=0THEN110
3210 PRINT TAB(12);'ПРАВИЛА ИГРЫ "ИМИТАЦИОННАЯ МОДЕЛЬ РЕГИОНА."'
3220 PRINT TAB(12);"------- ----  ------------ ------ --------"
3230 PRINT :PRINT "ДАННАЯ ИМИТАЦИОННАЯ ИГРА";:PRINT HEX(12);:PRINT "-ОБУЧАЮЩАЯ ИГРА, ПРЕДНАЗНАЧЕННАЯ ДЛЯ ПРИОБРЕТЕНИЯ";:PRINT HEX(11):PRINT "ПРАКТИЧЕСКИХ НАВЫКОВ ПО УРАВЛЕНИЮ СЛОЖНЫМИ СИСТЕМАМИ."
3270 PRINT "ЗДЕСЬ ПОД 'СЛОЖНОЙ СИСТЕМОЙ' ПОНИМАЕТСЯ МОДЕЛЬ РЕГИОНА, КОТОРАЯ СОСТОИТ ИЗ  СЛЕ-ДУЮЩИХ ХАРАКТЕРИЗУЮЩИХ ЕЕ ВЗАИМОСВЯЗАННЫХ ПАРАМЕТРОВ:"
3290 PRINT TAB(26);"1.НАРОДНОЕ ХОЗЯЙСТВО-"
3300 PRINT TAB(28);"ПОЛЕЗНЫЕ ИСКОПАЕМЫЕ, УСЛУГИ И Т. П. -- ВСЕ ЭТО В                                НАШЕМ СЛУЧАЕ ОБ'ЕДИНЕНО В ОДНОМ БЛОКЕ;"
3320 PRINT TAB(26);"2.ОКРУЖАЮЩАЯ СРЕДА;                                                             3.НАСЕЛЕНИЕ;                                                                    4.БЛАГОСОСТОЯНИЕ НАРОДА (ЗДОРОВЬЕ, ПИТАНИЕ И ДР.)"
3360 PRINT TAB(26);"5.ПРИБЫЛЬ -- ДЕНЕЖНЫЕ СРЕДСТВА, ЭНЕРГИЯ, ТОВАРЫ, ПИЩА."
3380 PRINT "ИГРА СОСТОИТ ИЗ ПОСЛЕДОВАТЕЛЬНОСТИ 25 ТУРОВ, ГДЕ КАЖДЫЙ ТУР -- УПРАВЛЯЮЩЕЕ ВОЗ- ДЕЙСТВИЕ НА СИСТЕМУ И ПОЛУЧЕНИЕ РЕЗУЛЬТАТОВ ЭТОГО ВОЗДЕЙСТВИЯ В ТЕЧЕНИЕ 1 ГОДА."
3400 PRINT :PRINT :PRINT "ПОД УПРАВЛЯЩИМ ВОЗДЕЙСТВИЕМ ПОНИМАЕТСЯ РАСПРЕДЕЛЕНИЕ ПРИБЫЛИ С ЦЕЛЬЮ ИЗМЕНЕНИЯ ЗНАЧЕНИЙ ПАРАМЕТРОВ МОДЕЛИ."
3430 PRINT :INPUT "ДЛЯ ПРОДОЛЖЕНИЯ ДИАЛОГА НАЖАТЬ 'CR/LF'   ",N
3450 PRINT "ЦЕЛЬ ИГРЫ ЗАКЛЮЧАЕТСЯ В ВЫБОРЕ ТАКОЙ ПОСЛЕДОВАТЕЛЬНОСТИ УПРАВЛЯЮЩИХ ВОЗДЕЙСТВИЙ,КОТОРАЯ БЫ ОБЕСПЕЧИЛА СТАБИЛЬНЫЙ РОСТ БЛАГОСОСТОЯНИЯ НАРОДА (КАЧЕСТВО ЖИЗНИ),   СТРЕМЯЩЕГОСЯ К НАИВЫСШЕМУ ЗНАЧЕНИЮ."
3480 PRINT :PRINT "ОБЯЗАТЕЛЬНО ЗАПОМНИТЕ СЛЕДУЩЕЕ :                                                В ТЕЧЕНИИ 25 ТУРОВ ВЫ ДОЛЖНЫ РАСПРЕДЕЛИТЬ ДЕНЕЖНЫЕ СРЕДСТВА (ПРИБЫЛЬ) НА:"
3500 PRINT TAB(22);"1. РАЗВИТИЕ Н/Х,"
3501 PRINT TAB(22);"2. ПОДДЕРЖАНИЕ ОКРУЖАЮЩЕЙ СРЕДЫ,"
3502 PRINT TAB(22);"3. КАЧЕСВО ЖИЗНИ (ПОВЫШЕНИЕ БЛАГОСОСТОЯНИЯ НАРОДА),"
3530 PRINT TAB(22);"4. УПРАВЛЕНИЕ РОЖДАЕМОСТЬЮ."
3540 PRINT "ПОМНИТЕ О ТОМ, ЧТО :"
3541 PRINT TAB(22);"1. ОТВЕТ ДОЛЖЕН БЫТЬ ТОЛЬКО ЧИСЛОВЫМ,"
3542 PRINT TAB(22);"2. ДРОБНОЕ ЧИСЛО НАБИРАТЬ ЧЕРЕЗ ТОЧКУ (НАПРИМЕР 2.55),"
3560 PRINT TAB(22);"3. ВЫ МОЖЕТЕ ВЛОЖИТЬ ВСЕ СРЕДСТВА В КАКОЙ-ЛИБО ОДИН БЛОК,"
3561 PRINT TAB(22);"4. ОСТАВИТЬ ЧАСТЬ ПРИБЫЛИ НА СЛЕДУЮЩИЙ ТУР,"
3562 PRINT TAB(22);"5. ВЛОЖИТЬ СРЕДСТВА В РАЗНЫЕ БЛОКИ,"
3590 PRINT TAB(22);"6. В УПРАВЛЕНИЕ РОЖДАЕМОСТЬЮ МОЖНО ЗА ОДИН ТУР ВКЛАДЫ-                             ВАТЬ НЕ БОЛЕЕ Е ЕДИНИЦЫ СРЕДСТВ,"
3600 PRINT TAB(22);"7. EСЛИ ВЫ ХОТИТЕ УМЕНЬШИТЬ ПРИРОСТ НАСЕЛЕНИЯ, ТО ОТВЕЧАЙ-                         TE ЧИСЛОМ БЕЗ ЗНАКА, ЕСЛИ УВЕЛИЧИТЬ - ЧИСЛОМ СО ЗНАКОМ                          МИНУС.":PRINT :PRINT 
3620 INPUT "ДЛЯ ПРОДОЛЖЕНИЯ ДИАЛОГА НАЖАТЬ 'CR/LF'   ",N:GOTO 110